@options;

@figure;
  A = point( -3.9 , -1.76 );
  B = point( 2.65 , -3.61 );
  sAB = segment( A , B );
  C = point( -3.39 , 2.31 )  { violetfonce , (-0.91,-0.87) };
  sBC = segment( B , C )  { rougefonce };
  sAC = segment( A , C )  { rougefonce };
  medCA = mediatrice( C , A )  { i };
  medAB = mediatrice( A , B )  { i };
  E = intersection( medCA , medAB )  { i };
  ceEC = cercle( E , C )  { noir , 2 , i };

  D = pointaimante( -0.48 , 4.35 , DE=CE_20% )  { (-0.13,-0.9) };
  angleACB = angle( A , C , B )  { rougefonce };
  I = milieu( A , B )  { i };
  J = pointsur( C , I , 0.2 )  { i };
  var angC = abs(ACB) { 52.7171967068 };
  texte2 = texte( J ,"$angC$ °")  { rougefonce , (-1,0) , dec2 , gras };
  angleADB = angle( A , D , B )  { noir };
  K = pointsur( D , I , 0.2 )  { i };
  var angD = abs(ADB) { 50.702953265 };
  texte3 = texte( K ,"$angD$ °")  { noir , (-1,0) , dec2 , gras };
  // variable conditionnelle de base;
  varsi etat = [DE=CE_2%,1,0] { 0 };

  //Coloriage conditionnelle de AD et BD;
  varsi z = [etat=1,"rouge","bleu"] { bleu };
  sAD = segment( A , D )  {$z$ , bleuocean };
  sBD = segment( B , D )  {$z$ , bleuocean };
  //;
  // Trace conditionnelle de D;
  var xD = abscisse(D) { -0.48 };
  var yD = ordonnee(D) { 4.35 };
  varsi z1 = [etat=1,"trace","pastrace"] { pastrace };
  D1 = point( xD , yD )  {$z1$ , sansnom };
 var xA = abscisse(A) { -3.9 };
  var xB = abscisse(B) { 2.65 };
  var yA = ordonnee(A) { -1.76 };
  var yB = ordonnee(B) { -3.61 };
  var xC = abscisse(C) { -3.39 };
  var yC = ordonnee(C) { 2.31 };
  var positionC = (xC-xA)(yB-yA)-(yC-yA)(xB-xA) { -27.602 };
  var positionD = (xD-xA)(yB-yA)-(yD-yA)(xB-xA) { -46.3475 };
  var positio = positionC*positionD { 1279.283695 };
  varsi configuration = [positio>0,1,2] { 1 };
  //;
  // Affichage des textes;
  varsi bilan1 = [etat=1,[configuration=1,1,0],0] { 0 };
  texte4 = µ(bilan1) texte( -4 , 7 ,"Les angles ACB et ADB sont égaux")  { noir , dec2 , gras , italique };
  varsi bilan2 = [etat=1,[configuration=2,1,0],0] { 0 };
  texte5 = µ(bilan2) texte( -4 , 7 ,"Les angles ACB et ADB sont supplémentaires")  { noir , dec2 , gras , italique };
  // FIN !;

@config;
couleurfonddessin=0xffffff;